在前面介紹exynos4412芯片啟動過程時，我們知道：一上電，exynos4412首先執行固化在iROM中的代碼，iROM首先設置程序運行環境(比如關看門狗、關中斷、關MMU、設置棧、設置棧、啟動PLL等)，然后根據OM引腳確定啟動設備(NAND Flash/SD卡/其他)，把BL1從里面讀出存入iRAM的0x02021400地址處，然后開始啟動BL1；BL1從SD卡適當的位置讀入14K字節的數據，存在iRAM地址0x02023400處，所以BL2不能大于(14K–4) 字節，這里引出了為什么寫這一節的原因：如果我們的程序很大，大于14K怎么辦？

運行地址和鏈接地址：

運行地址是程序當前所處的地址，即程序在運行時，所處的當前地址。

鏈接地址是程序的鏈接地址，即程序運行時應該位于的運行地址。編譯程序時，可以在鏈接腳本中指定程序的鏈接地址。

對于tiny4412而言，前面我們已經說過：啟動時BL1只會從sd等啟動設備中拷貝14K的代碼到iRAM中，那么當我們的程序超過14K怎么辦？那就需要我們在前14K的代碼中將整個程序完完整整地拷貝到LPDDR等其他更大存儲空間，然后再跳轉到LPDDR中繼續運行我們的代碼，這個拷貝然后跳轉的過程就叫重定位。

本章中講解學習如何重定位，但是并不會涉如何使用到LPDDR，而是簡單地將代碼從iRAM的0x02023400處拷貝到iRAM的0x02026400處，然后跳轉到0x02026400處繼續運行我們的代碼。

程序文件介紹：

1.start.S文件內容介紹：

.text

.global _start

_start:

//關閉看門狗;關于看門狗的設置可以查看Spec 1357頁

ldr r0, =0x10060000 //將0x10060000數字保存到R0寄存器中

mov r1, #0x0 //將0x0數字保存到R1寄存器中

str r1, [r0] //將R1寄存器中的數字(0)保存到R0寄存器數字表示的地址中

//重定位整個代碼到0x0202_6400地址處;這個地址位于iRAM里面

adr r0, _start //將_start標號(程序的開始地址)位于iRAM里的實際地址保存到R0寄存器中;也是開始拷貝程序的地址

ldr r1, =_start //獲取鏈接地址;也就是想將程序運行的地址;將拷貝的程序從這個地址開始保存

ldr r2, =bss_start //將鏈接地址中的bss_start標識地址保存到R1寄存器中;也是拷貝程序結束的地址;R1-R2的大小也就是要

//重定位代碼的大小

cmp r1, r2 //比較兩個地址是否相等,如果相等在直接去清除bss段即可;

beq clear_bss //跳轉到清零bss處

reload_loop:

ldr r3, [r0], #4 //將R0數字表示地址處的數據加載到R3寄存器中;并將R0+4

str r3, [r1], #4 //將R3中的數據保存到R1寄存器數字表示的地址中,并將R1+4

cmp r1, r2

bne reload_loop //循環拷貝

clear_bss: //將bss段清零

ldr r0, =bss_start //將bss段的開始地址保存到R0寄存器

ldr r1, =bss_end //將bss段的結束地址保存到R1寄存器

mov r2 ,#0x0 //將0數字保存到R2寄存器中

cmp r0, r1 //如果相等則表示bss清零完畢,跳轉執行點亮LED

beq run_address

clear_loop:

str r2, [r0], #4 //將0保存到R0寄存器地址,并將R0+4

cmp r0, r1

bne clear_loop //如果不相等則表示沒有清零完成

run_address: //點亮LED燈

ldr sp, =0x02027400 //設置棧

ldr pc, =main //使用絕對跳轉指令

//bl main

halt_loop: //死循環

b halt_loop

程序中已經做了詳細的注釋，這里就不再詳細介紹。

2.main.c文件詳細介紹：

//定義兩個宏，方便操作使用到的寄存器

#define GPM4_CON (*(volatile int *)0x110002E0)

#define GPM4_DAT (*(volatile int *)0x110002E4)

int main()

{

//設置GPM4_0引腳為輸出

GPM4_CON &= ~0xFF; //GPM4CON寄存器的低8位清零

GPM4_CON |= 0x11; //GPM4CON寄存器的bit0/4置1,設置為輸出引腳

//設置GPM4_0引腳為低電平

GPM4_DAT &= ~0x3; //GPM4DAT寄存器bit0/1清零,輸出低電平

return 0;

}

程序中已經做了詳細的介紹，這里不再介紹。

3.鏈接腳本：

SECTIONS {

. = 0x02026400; /* 鏈接地址 */

. = ALIGN(4);

.text : 

{ 

*(.text) 

}

. = ALIGN(4);

.rodata : 

{

*(.rodata)

}

. = ALIGN(4);

.data : 

{ 

*(.data) 

}

. = ALIGN(4);

bss_start = .; /* bss段的開始位置 */

.bss : 

{ 

*(.bss) *(.COMMON) 

}

bss_end = .; /* bss段的結束位置 */

}

鏈接腳本的內容很簡單，起始地址是0x02026400，并獲取了bss段的起始和結束地址。

按照前面文章講解的編譯和燒寫命令，將程序燒寫到SD卡中，設置SD卡啟動，觀察現象，發現LED1/2被點亮。說明程序重定位成功。

完畢！