從圖上可以清楚的看出：點鈔機的外接顯示屏主要由 單片機 Atmel公司生產(chǎn)的AT89C2051、三只七段共陽數(shù)碼管LED1~LED3、晶體三極管V1~V3和相應(yīng)的電阻電容及插頭所組成。

    大家知道，LED數(shù)碼管是由發(fā)光二極管作為顯示字段的數(shù)碼型顯示器件。在數(shù)碼管顯示器中，一般情況下都采用動態(tài)掃描式顯示方式。所謂掃描式，就是當(dāng)有多個七段（帶小數(shù)點的為八段）顯示器要顯示時，將其各個對應(yīng)引腳接在一起，也就是說，所有的a段接在一起，b段也接在一起，依此類推。而利用各七段顯示器的共陽（或共陰）極來確定哪一個七段顯示器要顯示。這樣做的目的有二：（1）省電；（2）節(jié)省輸出端口。

    本電路利用89C2051的端口與數(shù)碼的筆段接法為： P1.1-->C; P1.2-->D; P1.3-->E; P1.4-->B; P1.5-->A; P1.6-->F; P1.7-->G ，且三只數(shù)碼管的筆段a~g又是并聯(lián)在一起的。數(shù)碼管的公共端com分別由 P3.5-->V1; P3.4-->V2; P3.7-->V3 進(jìn)行控制。

   這里順利說明下，不知大家是否看出，無論是段碼還是公共端都沒有按相應(yīng)引腳順序來接，這是為什么？在實際應(yīng)用中，經(jīng)常會有這種接法，這就是我們通常所說的“硬件加密”法。

   P1口是一8位雙向I/O口，口引腳P1.2~P1.7提供內(nèi)部上拉電阻。P1.0和P1.2要求外上接電阻。尤其是P1.0這個上接電阻接在了點鈔機的主控板上，若要單獨使用這個顯示器，不要忘了加只5.1K的上接電阻。

    工作原理說明如下：

    1. 欲使LED1顯示器亮，需使V1導(dǎo)通，即P3.5=0，同理LED2欲亮?xí)r，P3.4=0。

    2. 由于共享a~g引腳，因此一次只能導(dǎo)通一個晶體管，否則會同時顯示相同的數(shù)字。

    3. 利用視覺暫留原理，V1~V3導(dǎo)通頻率16次/秒以上，注意頻率太低數(shù)字會閃爍，頻率太高數(shù)字會模糊變暗。

    4. 顯示數(shù)字時，須先送FFH到P1口關(guān)閉LED，再送顯示碼，否則容易造成視覺干攏。

    5. R3為限流電阻。

    通過對LED數(shù)碼管顯示原理的了解，再明確一下點鈔機外接顯示器的功能，你到銀行存過款嗎？當(dāng)你將錢交給營業(yè)員后，她就會將錢放入點鈔機，一是為了點數(shù)，二是為了鑒別鈔票的真?zhèn)巍Ｍ瑫r在柜臺上會有一個顯示器，使你也能看到你的錢幣的張數(shù)。這個顯示器就是點鈔機的外接顯示器，它顯示的數(shù)字與點鈔機是同步的，清點完之后，數(shù)字會一直保持，待下一次清點時，它會自動復(fù)位，從零開始進(jìn)行累加。

   數(shù)碼管的顯示原理和點鈔機外接顯示器的基本功能搞清楚之后，下面我們就開始編寫程序。

   外接顯示器共陽LED數(shù)碼管顯示段編碼

鈔機外接顯示屏的匯編程如下：
;* 標(biāo)題：點鈔機外接顯示屏

;* 描述: 采用AT89C2051芯片,晶振頻率:11.0592MHz。 
;* 初始狀態(tài)數(shù)碼管個位顯示"0",最大計數(shù)范圍: 999。 
LED1 BIT P3.5    ;百位(定義數(shù)碼管公共端) 
LED2 BIT P3.4    ;十位 
LED3 BIT P3.7    ;個位 

JSQ0 DATA 50H    ;脈沖計數(shù)單元高字節(jié) 
JSQ1 DATA 51H    ;脈沖計數(shù)單元低字節(jié) 

LED01 DATA 3AH    ;顯示段碼緩存器(百位) 
LED02 DATA 3BH    ;十位 
LED03 DATA 3CH    ;個位 
R31 DATA 1FH 
;* =======================================================* 
      ORG 0000H 
      AJMP START      ;復(fù)位轉(zhuǎn)主程序 
      ORG 0003H       ;INT0的入口地址 
      AJMP INT0_P32  
;* ------------------------------------------------------ * 
; 主程序0030H單元開始 
;* ------------------------------------------------------ * 
       ORG 0030H     ;跳過中斷向量區(qū) 
START:  MOV  R0,#7FH 
       CLR A 
DEL1:   MOV  @R0,A     ;預(yù)使用單元清0 
       DJNZ R0,DEL1 
MAIN:   MOV  SP,#60H   ;60H為棧頂位置初值 

       SETB IT0      ;置INT0為邊沿觸發(fā)方式 
        MOV  IP,#00000001B ;置INT0為高優(yōu)先級中斷 
        MOV  IE,#10000001B ;INT0開中 
        MOV  JSQ0,#0    ;計數(shù)單元清0 
        MOV  JSQ1,#0 
       CLR P1.0       ;注意在軟件模擬調(diào)試時,P1.0由于沒有接外部上拉電阻, 
                      ;拉低后就無法拉高.為了調(diào)試方便可選取89C51進(jìn)調(diào)試  
;*--------------------------------------------------------*  
DIR0_0:JB P1.0,DIR0_01 ;當(dāng)點鈔機已復(fù)位,但未放入紙幣,所以未中斷  
        MOV  R31,#28 
       ACALL DELAY2    ;延時1ms,去抖動 
       JB P1.0,DIR0_01 
       SETB P1.0 
        MOV  JSQ0,#0     ;復(fù)位信正確,計數(shù)單元清0 
        MOV  JSQ1,#0  
       ACALL HB2       ;將16進(jìn)制數(shù)轉(zhuǎn)換為BCD碼 
       ACALL THIF0     ;調(diào)用轉(zhuǎn)換顯示值子程序 
DIR0_01: 

        MOV  A,LED01     ;當(dāng)十位,百位數(shù)=0時,將其屏蔽  
       CJNE A,#81H,DIR0_02  
        MOV  LED01,#0FFH 
        MOV  A,LED02 
       CJNE A,#81H,DIR0_02 
        MOV  LED02,#0FFH 
DIR0_02: 
       SETB LED1       ;LED1位顯示停 
        MOV  P1,LED03    ;讀個位段碼 
       CLR LED3        ;LED1個位顯示 
        MOV  R31,#42 
       ACALL DELAY2    ;延時2ms 

SETB LED3       ;LED1位顯示停 
MOV  P1,LED02    ;讀十位段碼 
CLR LED2        ;LED2十位顯示 
MOV  R31,#42 
ACALL DELAY2 
SETB LED2       ;LED2十位顯示停 

MOV  P1,LED01    ;讀百位段碼 
CLR LED1        ;LED1百位顯示 
MOV  R31,#42  
ACALL DELAY2 

       AJMP DIR0_0     ;不斷循環(huán)顯示,并等待中斷 
;* =======================================================* 
;計數(shù)復(fù)位時,點鈔機主程序會先給出一個復(fù)位信號,并持續(xù)一段時間, 
;接著給出計數(shù)脈沖 
INT0_P32: 
       PUSH ACC        ;保護(hù)現(xiàn)場 
       PUSH DPH 
       PUSH DPL  
       JB P1.0,INT0_01 ;當(dāng)點鈔機  
        MOV  R31,#28 
       ACALL DELAY2    ;延時1ms,去抖動 
       JB P1.0,INT0_01 
       SETB P1.0       ;清除復(fù)位信號 
        MOV  JSQ0,#0     ;復(fù)位信正確,計數(shù)單元清0 
        MOV  JSQ1,#0  
INT0_01: 
       MOV  A,JSQ1       ;低字節(jié)計數(shù)單元加1 
      INC A 
       MOV  JSQ1,A 
      JNZ INT0_02 
      INC JSQ0         ;當(dāng)有進(jìn)位時,高字節(jié)單元加1 
INT0_02:  
      ACALL HB2        ;將16進(jìn)制數(shù)轉(zhuǎn)換為BCD碼 
      ACALL THIF0      ;調(diào)用轉(zhuǎn)換顯示值子程序 
      POP DPL          ;恢復(fù)現(xiàn)場 
      POP DPH 
      POP ACC  
      RETI             ;中斷返回 
;* =======================================================* 
;* 雙字節(jié)十六進(jìn)制整數(shù)轉(zhuǎn)換成雙字節(jié)ＢＣＤ碼整數(shù) 
;入口條件：待轉(zhuǎn)換的雙字節(jié)十六進(jìn)制整數(shù)在R6、R7中。 
;出口信息：轉(zhuǎn)換后的三字節(jié)ＢＣＤ碼整數(shù)在R3、R4、R5中。 
;影響資源：PSW、A、R2～R7堆棧需求： ２字節(jié) 
;* =======================================================* 
HB2:  
      MOV  R6,JSQ0       ;高字節(jié)單元送入R6 
      MOV  R7,JSQ1       ;低字節(jié)單元送入R7 

     CLR A             ;BCD碼初始化 
      MOV  R3,A 
      MOV  R4,A 
      MOV  R5,A 
      MOV  R2,#10H       ;轉(zhuǎn)換雙字節(jié)十六進(jìn)制整數(shù) 
HB3: 
      MOV  A,R7          ;從高端移出待轉(zhuǎn)換數(shù)的一位到CY中 
     RLC A 
      MOV  R7,A 
      MOV  A,R6 
     RLC A 
      MOV  R6,A 
      MOV  A,R5          ;BCD碼帶進(jìn)位自身相加,相當(dāng)于乘2 
     ADDC A,R5 
     DA A              ;十進(jìn)制調(diào)整 
      MOV  R5,A 
      MOV  A,R4 
     ADDC A,R4 
     DA A 
      MOV  R4,A 
      MOV  A,R3 
     ADDC A,R3 
      MOV  R3,A          ;雙字節(jié)十六進(jìn)制數(shù)的萬位數(shù)不超過6,不用調(diào)整 
     DJNZ R2,HB3       ;處理完16bit 
     RET 
;* =======================================================* 
;* 將BCD碼解壓后,轉(zhuǎn)換為十進(jìn)制顯示符 
;* =======================================================* 
THIF0:                 ;將壓縮BCD碼解壓(因最大數(shù)為999,所以[R3]=0)  
      MOV  A,R5          ;取數(shù)據(jù) 
     ANL A,#0FH        ;屏蔽高4位,取出低4位 
      MOV  32H,A         ;存?zhèn)€位 
      MOV  A,R5 
     SWAP A            ;交換 
     ANL A,#0FH 
      MOV  31H,A         ;存十位  
      MOV  A,R4          ;取數(shù)據(jù) 
     ANL A,#0FH        ;屏蔽高4位,取出低4位 
      MOV  30H,A         ;存百位 
;* 將BCD轉(zhuǎn)換為十進(jìn)制顯示符 
      MOV  DPTR,#TABD    ;置數(shù)碼表首址 
      MOV  R0,#30H       ;置顯示數(shù)首址 
      MOV  R1,#LED01     ;置字段碼暫存器首址 
      MOV  R2,#03H       ;置循環(huán)數(shù) 
THIF1: 
      MOV  A,@R0         ;取顯示數(shù) 
      MOV C A,@A+DPTR    ;讀字段碼 
      MOV  @R1,A         ;存字段碼 
     INC R0            ;修改顯示數(shù)地址 
     INC R1            ;修改字段碼暫存器地址 
     DJNZ R2,THIF1     ;判斷循環(huán)是否結(jié)束  
     RET 
TABD: 
     DB 81H,0EDH,43H,49H,2DH,19H ;共陽字段表,0～5顯示符 
     DB 11H,0CDH,01H,09H         ;6～9顯示符  
;* =======================================================*  
;* 延時子程序 
DELAY2:  
L2:  PUSH R31 
L3:  DJNZ R31,L3 
     POP R31 
     DJNZ R31,L2  
     RET 
END